Question

وظيفة الدالة SUMIFS شرح دالة SUMIFS بالتفصيل استخدام دالة SUMIFS

 SUMIFS شرح pdf ما هي دالة SUMIF دالة SUMIF بشرطين الفرق بين sumif و sumifs

وظيفة الدالة SUMIFS 

مرحباً بكم زوارنا الكرام في موقعنا النورس العربي منبع المعلومات والحلول يسرنا بزيارتكم أن نقدم ما هي وظيفة الدالة SUMIFS شرح دالة SUMIFS بالتفصيل استخدام دالة SUMIFS

الإجابة الصحيحة هي 

الدالة SUMIFS

بمعيار واحد SUMIFS

مع التواريخ SUMIFS

 مع استبعاد الخلايا الفارغة SUMIFS 

وفي منشور لاحق سنتعرف على استخدامات اخرى باذن الله

اولا:

بمعيار واحد SUMIFS

الصيغة البسيطة التالية 

=SUMIFS(G5:G16;B5:B16;C19)

نحدد عمود الجمع اولا ثم عمود المعيار ثم خلية المعيار او يمكن كتابة المعيار بين علامتي تنصيص " "

ثانيا:

مع التواريخ SUMIFS

=SUMIFS(G5:G16;C5:C16;D19;F5:F16;">30/4/2023")

نحدد عمود الجمع ثم عمود المنتج المراد مجموعه ثم عمود التاريخ والمعيار مع استخدام العلامات الحسابية اكبر من او اصغر من او يساوي ويمكن استخدام اكثر من معيار كما سيأتي لاحقاً

=SUMIFS(G5:G16;C5:C16;D19;F5:F16;">"&J14;F5:F16;"<"&I14)

نفس الصيغة السابقة سوى اننا نريد من تاريخ الى تاريخ 

لذلك سنحدد عمود الجمع ثم عمود المنتج فمعيار المنتج ثم عمود التاريخ مرتين مرة لاكبر من والثاني لاصغر من ويمكن كتابة التاريخ بين علامتي تنصيص ""

ثالثاً :

 مع استبعاد الخلايا الفارغة SUMIFS 

=SUMIFS(G5:G16;C5:C16;D19;D5:D16;"<>";E5:E16;"<>")

تماما كالسابقة سوى تغيير المعيار الى لا تساوي فراغ ان كان بالجدول خانات غير مكتملة 

انظر الصور 

كما هو معروف بأن هذه الدالة متعددة المعايير تستخدم بطرق لا حصر لها وتعرفنا في المنشور السابق على 3 طرق وسنتعرف في هذا المنشور على 3طرق أخرى وطريقة بديلة لها وهي دالة SUMPRODUCT

 SUMIFS مع معيار 1 أو معيارين

SUMIFS مع أحرف البدل

SUM مع SUMIFS

 SUMPRODUCT بديل SUMIFS

# مع معيار 1 أو معيارين SUMIFS

والصيعة هكذا

=SUMIFS(G5:G16;C5:C16;D19;E5:E16;D20)+SUMIFS(G5:G16;C5:C16;F19;E5:E16;F20)

نفس الدالة نجمع معها المعيار الثاني وعند تسجيل احد المعيارين يكون الناتج له وان تم تسجيل المعيارن يكون الناتج لهما ( انظر الصورة)

# مع أحرف البدل SUMIFS

والصيغة كما يلي 

=SUMIFS(G5:G16;C5:C16;D19;D5:D16;D20)

في الصيغة اعلاه نلاحظ كما بالصورة المعيار هو الحرفان *OC* 

هنا المعيار نبحث عن الموديل الذي يحتوي على هذين الحرفين بغض النظر على الحروف التي تسبقهما او تليهما ( كما بالصورة)

 ء SUM مع SUMIFS

والصيغة هكذا  

=SUM(SUMIFS(G5:G16;C5:C16;D19;E5:E16;{"امريكا","اليابان"}))

كتابة المعايير مباشرة داخل علامتي تنصيص واقواس معقوفة { " " }

أو هكذا

=SUM(SUMIFS(G5:G16;C5:C16;D19;E5:E16;D20)+SUMIFS(G5:G16;C5:C16;D19;E5:E16;D21))

وهي نفس الصيغة التي مع معيار او معيارين 

 ء SUMPRODUCT بديل SUMIFS

ما لا يعلمه الكثير ان دالة SUMPRODUCT تؤدي عمل نفس الدالة بطريقة بسيطة 

=SUMPRODUCT((G5:G14)*(C5:C14=D17)*(E5:E14={"امريكا","اليابان"}))

أو 

=SUMPRODUCT((G5:G14)*(C5:C14=D17)*((E5:E14=D18)+(E5:E14=D19)))

Answer 1

وتستمر الدالة SUMIFS بطرق أخرى

استخدام SUMIFS مع MATCH و OFFSETو COUNT

الصيغة هي

=SUMIFS(OFFSET(C4;1;MATCH(D16;D4:F4;0);COUNT(F:F);1);عميل;D15)

يمكن تسمية نطاق العملاء ( عميل )

وعمل قائمة منسدلة للعميل والسنوات في المعيار لتكون الدالة ديناميكية تختلف باختلاف احدهما او كلاهما معا

نستخدم المرجعC4 )OFFSET) لعمود 1  

ونستخدم الدالة MATCH للبحث عن ما يقابل الخلية D16 في الصف D4:F4 وهو صف الشهور ( وهذه الدالة تعتبر العمود لدالة OFFSET) المراد نقله من نقطة البداية

دالة OFFSET تحتاج الى 5 قيم

الرقم المرجعي نحدده بعمود (C4) وهذا الرقم مطلوب واجباري

الصفوف المراد ( اجباري) نقلها رقم سالب لاعلى وموجب لاسفل من نقطة البداية

الاعمدة المراد ( اجباري) تحريكها يسار رقم سالب ويمين رقم موجب من نقطة البداية

الطول( اخيتاري) عدد الصفوف المراد ارجاعها يمكن اهماله

العرض عدد الاعمدة يمكن اهمالها ايضا.

انظر الصورة لنفهم القصد واكتب الجدول عندك والدالة وقف بعد كل فاصله في شريط الصيغة لتعرف المطلوب

ونستمر مع دالة SUMIFS

استخدام SUMIFS مع MATCH و OFFSET و COUNT

الصيغة كما يلي

=SUMIFS(OFFSET(C4;1;MATCH(D16;D4:F4;0);COUNT(F:F);1);عميل;D15)

نعمل تسمية نطاق للعملاء

وقوائم منسدلة للعملاء والشهور لتصبح الصيغة ديناميكية تتغير باختلاف اي معيار

أيضاً SUMIFS

والجمع بين INDEX-MATCH وSUMIFS

 =SUMIFS(INDEX(B4:G17;;MATCH(C21;B4:G4;0));B4:B17;">="&C22;B4:B17;"<="&C23)

لدينا الجدول السابق لمبيعات عدة مناديب ونريد معرفة مندوب محدد ولفترة زمنية محددة

نستخدم الدالة المتداخلة السابقة

نستخدم INDEX لتحديد مصفوفة ونحدد كامل الجدول

ثم نستخدم MATCH لتحديد قيمة البحث عن المناديب وهو رأس الصفوف من B4:G4 ( وهاتان الدالتان نعتبرهما المعيار الأول )

 ويلاحظ بأننا نقوم بغلق قوسين واحد INDEX والآخر MATCH

ثم نأتي للمعيار الثاني وهو عمود التاريخ يكون التاريخ اكبر من او يساوي ما هو بالخلية C22

ثم المعيار الثالث نفس عمود التاريخ ويكون التاريخ اقل من او يساوي ما هو بالخلية C23

SUMIFS      

                         بمعايير متعددة لمجموع الأعمدة المتعددة

وصيغة الدالة هكذا

=SUMIFS($F$5:$F$13;$C$5:$C$13;$C$15;$D$5:$D$13;">="&$C$16;$D$5:$D$13;"<="&$C$17)

يمكن استخدام نفس الدالة بشكل رأسي للأعمدة عكس المنشور السابق الذي استخدمنا معه نطاق الصف والنتيجة واحدة

وهناك احد الاساتذة الافاضل في المنشور السابق قال ( بدلا من هذه اللفة استخدام الدالة DSUM )

ونحن هنا لا نتحدث عن الحلول واستخراج النتيجة ولكن نتحدث عن دالة محددة وهناك اكثر من طريقة لاستخراج نفس النتيجة بدءً من الدوال البسيطة الى الحديثة في 365 مرورا بالدوال المتداخلة والاكواد VBA

وهناك فرق جوهري بين الدوال

 والمنشور القادم بحول الله وقوته ، سنتعرض للدالة المنسية DSUM وطريقة استخدامها والفرق بينها وبين SUMIF